Андрей Попов - Windows Script Host для Windows 2000/XP

if (objNamedArgs.Exists("Имя")) s+=objNamedArgs("Имя")+"\n";

//Проверяем, существует ли аргумент /Comp:

if (objNamedArgs.Exists("Comp")) s+=objNamedArgs("Comp")+"\n";

WScript.Echo(s); //Выводим сформированные строки

/************* Конец *********************************************/

'********************************************************************

' Имя: Args.vbs

' Язык: VBScript

' Описание: Работа с аргументами запущенного сценария

'********************************************************************

Option Explicit

Dim i,Arg,objArgs,s,objNamedArgs,objUnnamedArgs ' Объявляем переменные

Set objArgs = WScript.Arguments ' Создаем объект WshArguments

' Определяем общее количество аргументов

s="Всего аргументов: " & objArgs.Count() & vbCrLf

For Each Arg In objArgs

s=s & Arg & vbCrLf ' Формируем строки со значениями аргументов

Next

Set objUnnamedArgs=objArgs.Unnamed ' Создаем объект WshUnnamed

' Определяем количество безымянных аргументов

s=s & vbCrLf & "Безымянных аргументов: " & objUnnamedArgs.length & vbCrLf

For Each Arg In objUnnamedArgs

' Формируем строки со значениями безымянных аргументов

s=s & Arg & vbCrLf

Next

Set objNamedArgs=objArgs.Named ' Создаем объект WshNamed

' Определяем количество именных аргументов

s=s & vbCrLf & "Именных аргументов: " & objNamedArgs.Length & vbCrLf

' Проверяем, существует ли аргумент /Имя:

If objNamedArgs.Exists("Имя") Then

s=s & objNamedArgs("Имя") & vbCrLf

End If

' Проверяем, существует ли аргумент /Comp:

If objNamedArgs.Exists("Comp") Then

s=s & objNamedArgs("Comp") & vbCrLf

End If

WScript.Echo s ' Выводим сформированные строки

'************* Конец *********************************************

Любое приложение при завершении своей работы может возвращать операционной системе целое число — код выхода (обычно ненулевое значение этого кода указывает на то, что выполнение программы прервалось в силу той или иной ошибки).

Сама операционная система Windows не проверяет код завершения приложений.

В WSH код выхода из сценария задается с помощью параметра метода Quitобъекта WScript. В листингах 2.23 и 2.24 приведены сценарии, в которых код завершения выбирается в зависимости от того, какая кнопка нажата в диалоговом окне (рис. 2.9): кнопке OKсоответствует код 1, кнопке Отмена— код 0.

Рис. 2.9.Диалоговое окно, создаваемое в сценарии Quit.js

/*******************************************************************/

/* Имя: Quit.js */

/* Язык: JScript */

/* Описание: Выход из сценария с заданным кодом завершения */

/*******************************************************************/

var WshShell,Res,Text,Title; //Объявляем переменные

var vbOkCancel=1,vbOk=1; //Инициализируем константы для диалоговых окон

//Создаем объект WshShell

WshShell = WScript.CreateObject("WScript.Shell");

Text="Выберите кнопку для завершения сценария";

Title="Диалоговое окно";

//Выводим диалоговое окно на экран

Res=WshShell.Popup(Text,0,Title,vbOkCancel);

if (Res==vbOk) WScript.Quit(1);

else WScript.Quit(0);

/************* Конец *********************************************/

'*******************************************************************

' Имя: Quit.vbs

' Язык: VBScript

' Описание: Выход из сценария с заданным кодом завершения

'*******************************************************************

Option Explicit

Dim WshShell,Res,Text,Title ' Объявляем переменные

' Создаем объект WshShell

Set WshShell = WScript.CreateObject("WScript.Shell")

Text="Выберите кнопку для завершения сценария"

Title="Диалоговое окно"

' Выводим диалоговое окно на экран

Res=WshShell.Popup(Text,0,Title,vbOkCancel)

If Res=1 Then

WScript.Quit 1

Else

WScript.Quit 0

End If

'************* Конец *********************************************

Если сценарий запускался с помощью командного файла, то код выхода можно проанализировать с помощью оператора IF ERRORLEVEL.

Пример подобного ВАТ-файла приведен в листинге 2.25. Здесь сценарий Quit.js запускается с помощью команды STARTс ключом /WAIT, указывающим на то, что выполнение ВАТ-файла должно быть приостановлено до окончания работы Quit.js. После этого, если код завершения pавен 1 (в диалоговом окне сценария была нажата кнопка OK), происходит переход к метке :Okи выдача с помощью команды ECHOсоответствующего сообщения на экран.

Для корректного отображения на экране символов кириллицы в BAT-файлах должна использоваться DOS-кодировка.

Если же код завершения сценария Quit.js был равен 0 (в диалоговом окне была нажата кнопка Отмена), то управление перейдет к строке

ECHO Для выхода из Quit.js была нажата кнопка Отмена

@ЕСНО OFF

REM **************************************************************

REM Имя: check.bat

REM Язык: BAT-файл

REM Кодировка: DOS

REM Описание: Определение кода завершения для сценария Quit.js

REM **************************************************************

@ЕСНO OFF

ECHO Запускаем сценарий Quit.js...

START /W Quit.js

REM Определяем код завершения для сценария Quit.js

IF ERRORLEVEL 1 GOTO :Ok

ECHO Для выхода из Quit.js была нажата кнопка Отмена

GOTO :end

:Ok

ECHO Для выхода из Quit.js была нажата кнопка Ok

:end

Для того чтобы из сценария получить доступ к свойствам или методам внешнего сервера автоматизации, вначале надо "создать" соответствующий объект, т.е. загрузить в память экземпляр нужного СОМ-объекта и сохранить в переменной ссылку на этот объект. Напомним, что объект в сценарии может создаваться несколькими способами: