Дж. Кеоун - OrCAD PSpice. Анализ электрических цепей

Transistor -Biasing Circuit for pnp Ge

VCC 4 0 12

VA 1 2 0.2

F 1 3 VA 60

RF 2 3 50k

RE 1 0 50

RC 3 4 1k

.DC VCC 12V 12V 12V

.OP

.OPT nopage

.PRINT DC I(RC) I(RE) I(RF)

.END

Рис. 3.3. Схема смещения для германиевого pnp -транзистора

Рис. 3.4. Модель смещения для германиевого pnp -транзистора

Проведите анализ; затем нарисуйте стрелки, показывающие условные направления токов для pnp -транзистора. Убедитесь, что I E =6,311 мА, а I В =103,5 мкА. Почему некоторые из показанных токов резистора положительны, а другие отрицательны? Это необходимо согласовывать с порядком следования узлов в командах, вводящих R . Например, команда

RE 1 0 50

дает отрицательный ток I(RE). Это происходит потому, что ток в R E фактически течет от узла 0 к узлу 1. Внимательно следите за соответствием направления стрелок на схеме и порядком следования узлов в командах, вводящих резисторы во входном файле:

Transistor-Biasing Circuit for pnp Ge

VCC 0 4 12

VA 1 2 0.2

F 1 3 VA 60

RF 2 3 50k

RE 1 0 50

RC 3 4 1k

.DC VCC 12 12 12

.PRINT DC I(RC) I(RE) I(RF)

.OP

.OPT nopage

.END

Обратите внимание, что ток в R C на самом деле, скорее представляет собой ток эмиттера, чем ток коллектора. Вы понимаете почему? Ток коллектора показывается в выходном файле PSpice как ток источника тока, управляемого током, равный 6,208 мА. Сложите базовый ток с током коллектора и сравните сумму с током эмиттера.

Точной моделью для биполярных транзисторов, широко используемой при анализе на малых сигналах, является модель в h -параметрах, показанная на рис. 3.5. Эта модель с соответствующими значениями используется для анализа схем с общим эмиттером (ОЭ), общим коллектором (ОК) или общей базой (ОБ). Наша задача состоит в том, чтобы разработать версию этой модели, пригодную для использования в PSpice. Эта модель содержит ИТУТ для использования с h f и управляемого напряжением источника напряжения (ИНУН) для использования с h r. В модель на рис. 3.6 введен резистор RI для моделирования h i , E, чтобы определить hr, RO в качестве 1/ h 0, и F, чтобы определить h f .

Рис. 3.5. Модель в h-параметрах для транзистора

Рис. 3.6. Модель схемы с ОЭ, пригодная для анализа на PSpice

На рис. 3.7 приведена типовая схема усилителя с общим эмиттером (ОЭ), предназначенная для анализа. Более сложные схемы можно часто привести к этой форме, используя различные теоремы и методы упрощения. Заданы параметры элементов схемы: V S= 1 мВ, R S= 1 Ом, R i =1,1 кОм (h ie ), h r= 2,5·10 -4(коэффициент используется в Е ), h f =50 (коэффициент используется в F ), R 0=40 кОм=1/ h 0, и R L =10 кОм. Источник V 0=0 В необходим, чтобы создать независимый источник для команды ввода F .

Рис. 3.7. Модель схемы с общим эмиттером в h -параметрах, включающая источник питания и нагрузку

Хотя нас интересуют свойства схемы на малых сигналах, мы не будем использовать анализ для переменного тока. Причина состоит в том, что пока мы имеем дело с установившимися состояниями для малых сигналов переменного тока и в схеме отсутствуют реактивные элементы, мы можем использовать анализ PSpice на постоянном токе относительно амплитуд или действующих значений токов и напряжений. Программа PSpice не воспринимает разницы! В то же время вы должны понимать, что программа дает результаты для малых сигналов переменного тока и никак не учитывает постоянных напряжений и токов смещения.

Конечно, мы полагаем, что рабочая точка была выбрана правильно и работа происходит в активной области. Входной файл для анализа имеет вид:

Small Signal Analysis of Transistor Circuit Using h Parameters

VS 1 0 1mV

V0 3 3A 0

E 3A 0 4 0 2.5E-4

F 4 0 V0 50

RS 1 2 1k

R1 2 3 1.1k

R0 4 0 40k

RL 4 0 10k

.OP

.OPT nopage

.TF V(4) VS

.END

Выполните анализ и распечатайте выходной файл для дальнейшего изучения. Убедитесь, что I b =0,5 мкА; I с =20 мкА (вычисляется как (V)4/ R L ); полный коэффициент усиления по напряжению -200 (вычисляется как V(4)/VS); R i =2 кОм и R 0 = 8,4 кОм.

Поскольку R i включает R S , каково входное сопротивление со стороны базы транзистора? Это R i - R s =1 кОм. Также, поскольку R 0, включает R L , что является выходным сопротивлением со стороны коллектора (не включая R L )? Найдем его, используя проводимости: 1/ R 0=1,1905×10 -4; вычтем из этой величины 1/ R L =1×10 -4, что даст 1/ R' 0=0,1905×10 -4. Таким образом, R' 0=52,5 кОм.

Коэффициент передачи по напряжению от базы на коллектор V(4)/V(2)=–400. Коэффициент усиления по току A i=I L / I B =-20μkА/0,5μkА=-40. Выходной файл приведен на рис. 3.8.

Small-Signal Analysis of Transistor Circuit Using h Parameters

**** CIRCUIT DESCRIPTION

VS 1 0 1mV

V0 3 3A 0

E 3A 0 4 0 2,5E-4

F 4 0 V0 50

RS 1 2 1k

RI 2 3 1.1k

R0 4 0 40k

RL 4 0 10k

.OP

.OPT nopage

.TF V(4) VS

.END

SMALL SIGNAL BIAS SOLUTION TEMPERATURE = 27.000 DEG С

NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE

( 1) .0010 ( 2) 500.0E-06 ( 3) -50.00E-06 ( 4) -.2000

( 3A) -50.00E-06

VOLTAGE SOURCE CURRENTS

NAME CURRENT

VS -5.000E-07

V0 5.000E-07

TOTAL POWER DISSIPATION 5.00E-10 WATTS

**** OPERATING POINT INFORMATION TEMPERATURE = 27.000 DEG С

**** VOLTAGE-CONTROLLED VOLTAGE SOURCES

NAME E

V-SOURCE -5.000E-05

I-SOURCE 5.000E-07

**** CURRENT-CONTROLLED CURRENT SOURCES

NAME F

I-SOURCE 2.500E-05

**** SMALL-SIGNAL CHARACTERISTICS

V(4)/ VS = -2.000E+02

INPUT RESISTANCE AT VS = 2.000E+03

OUTPUT RESISTANCE AT V(4) = 8.400E+03

Рис. 3.8. Выходной файл анализа для схемы на рис. 3.7

Подводя итог, заметим, что анализ PSpice избавил вас от ряда вычислений, но без понимания направлений токов и полярностей напряжений ваше решение будет не завершено. Вы должны понимать, что теория h -параметров сочетается здесь с моделью PSpice, которую мы разработали. Необходимо помнить, что определение h -параметров зависит от конфигурации схемы.