А. Григорьев - О чём не пишут в книгах по Delphi

Все проблемы при присваивании сводятся к одному из этих случаев или к их комбинации.

Все эти ситуации при выключенной опции Range checkingприводят к ошибкам, которые бывает очень трудно обнаружить. Из-за этого рекомендуется включать эту опцию хотя бы на этапе отладки.

В некоторых случаях возможность присваивания значений, выходящих за пределы диапазона переменной, может быть необходимой (например, для реализации "хитрых" алгоритмов или при сопряжении сторонних библиотек, одна из которых использует знаковые типы, другая — беззнаковые). Чтобы включение ERangeErrorне возникало, следует предусмотреть явное приведение типа. Например, следующий код работает без исключений при включенной опции Range checking(листинг 3.3).

procedure TForm1.Button1Click(Sender: TObject);

var

X: Byte;

Y: ShortInt;

begin

Y := -1;

X := Byte(Y);

Label1.Caption := IntToStr(X)

end;

В результате его выполнения переменная Xполучает значение 255.

Переполнением принято называть ситуацию, когда при операциях над переменной результат выходит за пределы ее диапазона. Рассмотрим следующий пример (листинг 3.4, проект Overflow1 на компакт-диске).

procedure TForm1.Button1Click(Sender: TObject);

var X: Byte;

begin

X := 0;

X := X - 1;

Label1.Caption := IntToStr(X)

end;

Переменная Xполучит значение 255, поскольку при вычитании получается -1, что в беззнаковом формате соответствует 255. В принципе, этот пример практически эквивалентен примеру Assignment1, за исключением того, что значение -1 появляется в результате арифметических операций.

Немного изменим этот пример — заменим оператор вычитания функцией Dec(листинг 3.5, пример Overflow2 на компакт-диске).

{$R+}

procedure TForm1.Button1Click(Sender: TObject);

var X: Byte;

begin

X := 0;

Dec(X);

Label1.Caption := IntToStr(X);

end;

Результат получается тот же (X получает значение 255), но обратите внимание: несмотря на то, что опция Range checkingвключена, исключение не возникает. Этим пример Overflow2 отличается от Overflow1 — там исключение возникнет. Связано это с тем, что переполнение при использовании Decи подобных ей функций контролируется другой опцией — Overflow checking(в коде программы включается директивой {$Q+}или {$OVERFLOWCHECKS ON}). Эта опция по умолчанию тоже отключена и ее также рекомендуется включать при отладке. При ее включении в данном примере возникнет исключение EIntOverflow.

Посмотрим, что произойдет, если мы попытаемся сравнить знаковое и беззнаковое число (листинг 3.6, пример Compare1 на компакт-диске).

procedure TForm1.Button1Click(Sender: TObject);

var

X: Byte;

Y: ShortInt;

begin

Y := -1;

X := Y;

if X = Y then Label1.Caption := 'Равно';

else Label1.Caption := 'He равно';

end;

В окне появится надпись Не равно, хотя последовательность битов в переменных Xи Yбудет, как мы уже знаем, одинаковая. Надпись соответствует действительности — X(255) действительно не равно Y(-1). Разберемся, почему так происходит.

Те, кто успел самостоятельно откомпилировать пример Compare1, могли заметить предупреждение компилятора на строке со сравнением: "Comparing signed and unsigned types — widened both operands". Это предупреждение все объясняет: компилятор, зная, что совпадение наборов битов не гарантирует равенство знакового и беззнакового выражения, сначала "расширяет" типы выражений до того типа, чей диапазон целиком вмещает оба требуемых диапазона и лишь затем выполняет сравнение. Это обеспечивает правильный результат сравнения, но требует дополнительных ресурсов, поэтому компилятор выдает предупреждение.

Аналогичные действия компилятор выполнит при сравнении выражений типов Wordи SmallInt, а также LongIntи LongWord. Тип Int64 не имеет беззнакового аналога, поэтому операнды этого типа при сравнении компилятор не "расширяет".

Явное приведение типов позволяет избавиться от операций по расширению типа и ограничиться побитовым сравнением (листинг 3.7. пример Compare2 на компакт-диске).

procedure TForm1.Button1Click(Sender: TObject);

var

X: Byte;

Y: ShortInt;

begin

Y := -1;

X := Y;

if X = Byte(Y) then Label1.Caption := 'Равно'

else Label1.Caption := 'Не равно';

end;

При компиляции такого кода не выдается никаких предупреждений, но и результат сравнения будет неверным: Равно.

Операции >, <, >= и <= тоже работают по-разному для знаковых и беззнаковых чисел. Пусть, например, сравниваются числа 01000000 и 11000000. В беззнаковом формате это 64 и 192, поэтому первое число меньше второго. А в знаковом это 64 и -64, т. е. первое число больше. Из-за этого для операций сравнения для знаковых и беззнаковых чисел в системе команд процессора существуют разные команды. В литературе, чтобы подчеркнуть это, часто используются различные названия операций в зависимости от формата: для знаковых чисел — "больше" и "меньше", для беззнаковых — "выше" и "ниже".

Рассмотрим программу (пример ForRange на компакт-диске), на форме которой находятся кнопка и панель, причем кнопка (это важно!) — не на панели, а на форме, а на панели нет никаких компонентов. Обработчик нажатия на кнопку выглядит следующим образом (листинг 3.8).

procedure TForm1.Button1Click(Sender: TObject);

var

I: Cardinal;

begin

for I := 0 to Panel1.ControlCount - 1 do

Panel1.Controls[I].Tag := 1;

end;

На первый взгляд кажется, что при нажатии на кнопку ничего не должно происходить, т.к. на панели никаких визуальных компонентов нет, и цикл forне должен выполниться ни разу. Тем не менее нажатие на кнопку вызывает исключение Access violation.

При нулевом количестве компонентов на панели выражение Panel1.ControlCount - 1должно давать значение -1. Но поскольку переменная цикла имеет тип Сardinal, эта комбинация битов интерпретируется как 4 294 967 295, верхняя граница оказывается больше нижней, и цикл начинает выполняться, обращаясь к несуществующим элементам управления. Отсюда и ошибка.

Ошибка исчезнет, если тип переменной Iизменить на Integer— в этом случае верхняя граница цикла получит корректное значение -1, и цикл действительно не выполнится ни разу. Если на панели будет находиться хотя бы один компонент, ошибки тоже не будет, потому что верхняя граница цикла не выйдет из диапазона неотрицательных чисел.