А. Григорьев - О чём не пишут в книгах по Delphi

{

В этом модуле реализуется дополнительная нить UDP-чата, отвечающая за прием сообщений.

}

interface

uses

SysUtils, Classes, WinSock;

type

TReceiveThread = class(TThread)

private

// Сообщение, которое нужно добавить в лог,

// хранится в отдельном поле, т.к. метод, вызывающийся через

// Synchronize, не может иметь параметров.

FMessage: string;

// Сокет, получающий сообщения

FSocket: TSocket;

// Вспомогательный метод для вызова через Synchronize

procedure DoLogMessage;

protected

procedure Execute; override;

// Вывод сообщения в лог главной формы

procedure LogMessage(const Msg: string);

public

constructor Create(ServerSocket: TSocket);

end;

implementation

uses ChatMainUnit;

{TReceiveThread}

// Сокет, получающий сообщения, создается в главной нити,

// а сюда передаётся через параметр конструктора

constructor TReceiveThread.Create(ServerSocket: TSocket);

begin

FSocket := ServerSocket;

inherited Create(False);

end;

procedure TReceiveThread.Execute;

var

// Буфер для получения сообщения.

// Размер равен максимальному размеру UDP-дейтаграммы

Buffer: array[0..65506] of Byte;

// Адрес, с которого пришло сообщение

RecvAddr: TSockAddr;

RecvLen, AddrLen: Integer;

Msg: string;

begin

// Начинаем бесконечный цикл, на каждой итерации которого

// читается одна дейтаграмма

repeat

AddrLen := SizeOf(RecvAddr);

// Получаем дейтаграмму

RecvLen :=

recvfrom(FSocket, Buffer, SizeOf(Buffer), 0, RecvAddr, AddrLen);

// Так как UDP не поддерживает соединение, ошибку при вызове recvfrom

// мы можем получить, только если случилось что-то совсем

// экстраординарное. В этом случае завершаем работу нити.

if RecvLen < 0 then

begin

LogMessage('Ошибка при получении сообщения: ' + GetErrorString);

// Перевод элементов управления главной формы

// в состояние "Сервер не работает"

Synchronizе(ChatForm.OnStopServer);

Break;

end;

// Устанавливаем нужный размер строки

SetLength(Msg, RecvLen);

// и копируем в нее дейтаграмму из буфера

if RecvLen > 0 then Move(Buffer, Msg[1], RecvLen);

LogMessage('Сообщение с адреса ' + inet_ntoa(RecvAddr.sin_addr) + ':' +

IntToStr(ntohs(RecvAddr.sin_port)) + ':' + Msg);

until False;

closesocket(FSocket);

end;

procedure TReceiveThread.LogMessage(const Msg: string);

begin

FMessage := Msg;

Synchronize(DoLogMessage);

end;

procedure TReceiveThread.DoLogMessage;

begin

ChatForm.AddMessageToLog(FMessage);

end;

end.

Отправлять данные можно и из основной нити, поскольку функция sendtoпри наших объемах данных практически никогда не будет блокировать вызывающую ее нить (да и при больших объемах данных, как мы увидим в дальнейшем, этого практически никогда не бывает). Соответственно, нам нужно создать два сокета: один для отправки сообщений, другой для приема. Сокет для отправки сообщений создаем сразу же при запуске приложения, при обработке события OnCreateглавной (и единственной) формы. Дескриптор сокета хранится в поле FSendSocket. Пользователю не принципиально, какой порт займет этот сокет, поэтому мы доверяем его выбор системе (листинг 2.8).

procedure TChatForm.FormCreate(Sender: TObject);

var

// Без этой переменной не удастся инициализировать библиотеку сокетов

WSAData: TWSAData;

// Адрес, к которому привязывается сокет для отправки сообщений

Addr: TSockAddr;

AddrLen: Integer;

begin

// инициализация библиотеки сокетов

if WSAStartup($101, WSAData) <> 0 then

begin

MessageDlg('Ошибка при инициализации библиотеки WinSock',

mtError, [mbOK], 0);

Application.Terminate;

end;

// Перевод элементов управления в состояние "Сервер не работает"

OnStopServer;

// Создание сокета

FSendSocket := socket(AF_INET, SOCK_DGPAM, IPROTO_UDP);

if FSendSocket = INVALID_SOCKET then

begin

MessageDlg('Ошибка при создании отправляющего сокета:'#13#10 +

GetErrorString, mtError, [mbOK], 0);

Exit;

end;

// Формирование адреса, к которому будет привязан сокет

// для отправки сообщений

FillChar(Addr.sin_zero, SizeOf(Addr.sin_zero), 0);

Addr.sin_family := AF_INET;

// Пусть система сама выбирает для него IP-адрес и порт

Addr.sin_addr.S_addr := INADDR_ANY;

Addr.sin_port := 0;

// Привязка сокета к адресу

if bind(FSendSocket, Addr, SizeOf(Addr)) = SOCKET_ERROR then

begin

MessageDlg('Ошибка при привязке отправляющего сокета к адресу:'#13#10 +

GetErrorString, mtError, [mbOK], 0);

Exit;

end;

// Узнаем, какой адрес система назначила сокету

// Это нужно для вывода информации для пользователя

AddrLen := SizeOf(Addr);

if getsockname(FSendSocket, Addr, AddrLen) = SOCKET_ERROR then

begin

MessageDlg('Ошибка при получении адреса отправляющего сокета:'#13#10 +

GetErrorString, mtError, [mbOK], 0);

Exit;

end;

// Не забываем, что номер порта возвращается в сетевом формате,

// и его нужно преобразовать к обычному функцией htons.

LabelSendPort.Caption := 'Порт отправки: ' + IntToStr(ntohs(Addr.sin_port));

end;

Сокет для получения сообщений создается при нажатии кнопки Запуститьи привязывается к тому порту, который указал пользователь. В случае его успешного создания запускается нить, которой передается этот сокет, и все дальнейшие операции с ним выполняет эта нить. Нить вместе с этим сокетом мы будем условно называть сервером. Код обработчика нажатия кнопки Запуститьпоказан в листинге 2.9.

// Реакция на кнопку "Запустить"

procedure TChatForm.BtnStartServerClick(Sender: TObject);

var

// Сокет для приема сообщений

ServerSocket: TSocket;

// Адрес, к которому привязывается сокет для приема сообщений

ServerAddr: TSockAddr;

begin

// Формирование адреса сокета для приема сообщений

FillChar(ServerAddr.sin_zero, SizeOf(ServerAddr.sin_zero), 0);

ServerAddr.sin_family := AF_INET;

// IP-адрес может выбрать система, а порт назначаем тот,

// который задан пользователем

ServerAddr.sin_addr.S_addr := INADDR_ANY;

try

// He забываем преобразовать номер порта к сетевому формату

// с помощью функции htons

ServerAddr.sin_port := htons(StrToInt(EditServerPort.Text));

if ServerAddr.sin_port = 0 then

begin

MessageDlg('Номер порта должен находиться в диапазоне 1-65535',

mtError, [mbOK], 0);

Exit;

end;

// Создание сокета для получения сообщений

ServerSocket := socket(AF_INET, SOCK_DGRAM, IPPROTO_UDP);