Гэри Розенцвейг - Adobe Flash. Создание аркад, головоломок и других игр с помощью ActionScript

Рисунок 10.5. Шарики-захватчики движутся группой

Между тем лиса внизу движется слева направо и стреляет в шарики. Она должна перестрелять их всех, прежде чем группа шариков достигнет поверхности земли.

Подход

Поведение лисы может остаться таким же, как в первой игре этой главы. Но поведение шариков должно быть полностью изменено. К тому же во время игры не должно быть создано ни одного нового шарика. Они все появляются в начале игры.

Подготовка ролика

Как и в первой игре этой главы, есть кадр стоящей лисы – «stand», и анимация ходьбы. У шарика есть нормальный кадр и анимация взрыва. Все шарики сначала серого цвета и потом раскрашиваются с помощью ActionScript. Пуля – это короткий клип-линия.

Создание кода

Клип «actions» такой же, как в первой игре этой главы, за исключением того, что новые шарики не создаются в каждом кадре.

onClipEvent(load) {

_root.initGame();

}

onClipEvent(enterFrame) {

_root.moveBalloons();

_root.moveFox();

_root.moveBullets();

}

Функция initGame вызывает функцию createBalloons, чтобы создать группу шариков. Ей не нужно задавать такие переменные, как nextBalloonили создавать массив balloons,поскольку после начала игры новые шарики не создаются.

function initGame() {

// Создаем шарики.

createBalloons();

// Параметры снарядов.

nextBulletTime = 0;

nextBullet = 0;

bullets = [];

// Переменная счета.

score = 0;

}

Функция createBalloons создает 30 шариков в 10 колонках по 3 штуки в каждой. Каждая ссылка на шарик хранится в массиве. Цвет шарику назначается в зависимости от того, в каком он ряду. Каждому шарику придано начальное направление и скорость равная 3.

function createBalloons() {

balloons = new Array();

balloonNum = 0;

// Создаем новый ряд.

for(var y=0;y<3;y++) {

for(var x=0;x<10;x++) {

// Создаем и размещаем новый шарик.

attachMovie("balloon", "balloon"+balloonNum, balloonNum);

balloonClip = this["balloon"+balloonNum];

balloonClip._x = x*30+20;

balloonClip._y = y*30+20;

// Добавляем в массив.

balloons.push(balloonClip);

// Устанавливаем цвет.

balloonColor = new Color(balloonClip);

if (y == 0) {

balloonColor.setTransform({rb: 255});

} else if (y == 1) {

balloonColor.setTransform({gb: 255});

} else if (y == 2) {

balloonColor.setTransform({bb: 255});

}

balloonNum++;

}

}

// Направление (скорость)шариков.

balloonDirection = 3;

}

Функция moveBalloons двигает все шарики в массиве balloons.Если какой-нибудь из них дотронется до края экрана, то все они меняют направление. Если же какой-нибудь достигнет низа экрана, игра заканчивается.

function moveBalloons() {

// Переменная-флаг изменения направления.

var newDirection = false;

// Просматриваем все шарики.

for(var i=0;i

// Передвигаем текущий шарик.

balloons[i]._x += balloonDirection;

// Смотрим, не достиг ли шарик границы экрана.

if ((balloonDirection > 0) and (balloons[i]._x > 530)) {

newDirection = true;

} else if ((balloonDirection < 0) and (balloons[i]._x < 20)) {

newDirection = true;

}

}

// При столкновении с границой экрана

// шарики опускаются и меняют направление.

if (newDirection) {

balloonDirection *= -1;

for(var i=0;i

balloons[i]._y += 3;

}

}

// Не достигли ли шарики земли?

if (balloons[i-1]._y > 300) {

gotoAndStop("game over");

}

}

Все функции для создания лисы и пуль точно такие же, как и в первой игре главы, поэтому их код я здесь приводить не буду. Но функция checkCollision другая, поскольку она должна следить, не случилось ли так, что все шарики уничтожены, и заканчивать игру.

function checkCollision(bullet) {

// Просматриваем все шарики.

for(j=balloons.length-1;j>=0;j—) {

balloon = balloons[j];

// Смотрим не попала ли пуля в шарик.

if (distance(bullet,balloon) < 10) {

// Удаляем шар из массива.

balloons.splice(j,1);

// Переходим в кадр взрыва шарика.

balloon.gotoAndPlay(2);

// Увеличиваем счет.

score += 1;

// Если шаров больше нет – игра заканчивается.

if (balloons.length == 0) {

gotoAndStop("game over");

}

// Возвращаем значение true, так как попали в шарик.

return(true);

}

}

// Возвращаем false, поскольку попали в шарик.

return(false);

}

К сведению

Как и в исходной игре этой главы, здесь есть вводный и заключительный кадры. Я в обоих играх использую одинаковые кадры вне зависимости от того, выиграл игрок или проиграл. Вы можете сделать два разных кадра с соответствующим текстом в каждом.

Другие возможности

Чтобы сделать игру труднее, вы можете ускорить движение захватчиков. Сначала попробуйте увеличить расстояние, на которое они падают каждый раз. Также можно увеличить скорость, с которой они движутся из стороны в сторону.

Если вы хотите добавить в игру уровней, то можете создать переменную startSpeed,которая начинается со значения 3. Задайте эту скорость функции balloonDirection каждого шарика вместо жестко заданного "3". Пусть теперь после того, как все шарики выбиты, игрок переходит к экрану «level over». Когда он нажимает кнопку «play next level», startSpeedувеличивается, и ролик отправляется к кадру «play», где шарики появляются с новой, более высокой скоростью.

• Стена и мяч

• Мяч и бита

• Бита и блоки

• Бита и блоки в трех измерениях

Следующий жанр, который будет рассмотрен, восходит к первой видеоигре «Pong». Эта простая игра положила начало революции игровых автоматов в 70-х годах.

В таких играх задействован обычный мяч, отскакивающий от стен, и бита, управляемая пользователем. Игрок пытается не позволить мячу пролететь мимо биты.

В первой игре, которую вы создадите, будет только простая бита и мяч. Во второй игре появится вторая бита, управляемая компьютером, то есть у игрока будет противник, обладающий искусственным интеллектом. В третьей игре, которая описывается в данной главе, игрок будет пытаться выбить блоки с помощью мяча, как в классической игре "Breakout". Последняя игра раздела перенесет действие "Breakout" в трехмерное пространство.

Исходный файл: Wallball.fla

Первая игра называется "Стена и мяч". В ней имеются бита, управляемая пользователем, и три стены, от которых может отскакивать мяч. Четвертой стены нет (она открыта). Задача игрока состоит в том, чтобы не позволить мячу пролететь мимо биты (рис. 11.1).

Рисунок 11.1. Элементами игры «Стена и мяч» являются мяч, бита и три стены

Задача проекта

Цель данного проекта – создать игру, где двигающийся мяч будет отскакивать от стен и биты. Бита будет перемещаться по вертикали в соответствии с движением мыши. Если мяч пролетает мимо биты и достигает границы экрана, игра заканчивается. При столкновении мяча с битой скорость первого должна немного увеличиваться.

Подход

Самое сложное при создании этой игры – сделать так, чтобы мяч правильно отскакивал от стен. Многие программисты не учитывают ни диаметр мяча, ни его скорость. В результате может случиться, что мяч будет отскакивать не от стены, а от точки, расположенной за ней.

Рассмотрим ситуацию, когда мяч оказывается за стеной. При этом надо выяснить, насколько далеко залетел мяч за пределы игрового поля. Так как мяч перемещается на несколько пикселов в одном кадре, он может легко проскочить за стену на несколько пикселов.

Читать дальше